The apave software provides a sort of geometry manager for Tcl/Tk.

The apave isn't designed to replace the existing Tk geometry managers (place, pack, grid). Rather the apave tries to simplify the window layout by using their best, by means of:

• joining the power of grid and pack
• uniting a creation of widgets with their layout (and mostly their configuration)
• minimizing a coder's efforts at creating / modifying / removing widgets
• setting a natural tab order of widgets
• providing 'mega-widgets'
• providing 'mega-attributes', right up to the user-defined ones
• centralizing things like icons or popup menus
• theming both ttk and non-ttk widgets

Along with standard widgets, the apave objects can use a batch of following 'mega-widgets':

• file picker
• saved file picker
• directory picker
• font picker
• color picker (special for Linux)
• date picker
• calendar
• menubar
• toolbar
• statusbar
• file combobox
• file listbox
• file viewer/editor
• option cascade
• e_menu
• bar of tabs
• link
• gutter
• scrolled frame
• switch
• user widgets

Also, apave provides a bundle of nice little things like:

• button / label with a bound command to fire after a timeout
• progress form for a boot process presumably long
• blinking widgets to draw attention
• default context menus for entries and texts, incl. read-only ones
• configurable balloon messages and tooltips
• tagged texts
• changing images and links embedded into texts
• 25 light and 25 dark color schemes, optionally tinted
• 74 icons (small & large) for a good deal of occasions
• customized dimensions of Tcl/Tk Unix's file / directory choosers and enhanced color / date choosers
• integration with e_menu to expand an application's facilities
• opening dialogues as modal / non-modal, closed / not closed with Escape key
• simple [pobj Widget] instead of messy .win.fra1.fra2.and_so_on.widget for configurable widgets
• Hungarian notation for widget names consistently divided into ttk and non-ttk widgets

The apave is implemented as APave oo::class, so that you can enhance it with your own inherited / mixin-ed class.

The theming facility of apave is enabled by ObjectTheming oo::class which embraces both ttk and non-ttk widgets, as seen on Demo.

Note that bartabs, baltip and hl_tcl are contained in apave package as sort of subpackages and can be used independently.

On the other hand, having installed apave, you need not to install bartabs, baltip and hl_tcl.

There is one pitfall at this: if you use Magicsplat or BAWT Tcl/Tk distribution, you can find that they are including a bit obsolete version of apave or one of its subpackages. Or their versions aren't what you rely on. In this case, you should dismiss the preinstalled packages and likely use source for the main script of the package (apave.tcl for apave), this way:

foreach _ {apave baltip bartabs hl_tcl} {
  catch {
    package forget $_
    namespace delete $_
  }
}
unset -nocomplain _
source ./apave/apave.tcl

In fact, apave has been intended for those programmers who (like me) are too lazy in order to dig in the endless interference of grid and pack, the widget pathes and, most dreadful of all, the belated modifications of GUI.

The apave originates from the old pave package, to comply with How to build good packages ("avoid simple, obvious names for your namespace").
Let it be a sort of a-pave.

The main idea of apave is that while inserting or removing a cell you need to have in mind only its neighborhood. This way of thinking is applicable to a creation as well as to a modification of layout.

For example, while adding a new widget cell to the layout you need to have in mind only its top (T) or left (L) neighbor, this way:

Just at the adding, while inserting a widget in the middle of layout, you think only of its relation to a future T (L) neighbor. Thus, you always think of widgets in terms of relations to their neighbors who as such are easily observable. You never evaluate the widgets' absolute rows/columns and all appropriate correlations.

Another advantage of this "T/L layout" is that it sets a natural tab order of widgets. When you insert a new widget, at the run time it would be selected with Tab key just from its T/L neighbor. Thus, Top/Left widgets would naturally pass their selection to their Bottom/Right neighbors.

The second idea of apave is to minimize your key-pressing which is achieved through:

• smart naming of the widgets
• abbreviating of the widgets options
• default settings of most popular options (perhaps the scroll options are most odious)
• providing the popular pickers (file, directory, color etc.) as 'mega-widgets'

In practice you pass to apave a list containing the records (lists also) of the following structure:

For example, this code sample

. . .
{but4 . . .
{sehC but4 T 1 1 {-st ews}}
{butC sehC T 3 1 {-st we} {-t "Close All" -com "exit"}}
. . .

Notice also that

• the widgets are related as "T" neighbors (but4 is above sehC that is above butC)
• the widget attributes are omitted in the sehC
• the grid/pack options and both spans (being 1 as default) can be omitted as well
• the neighbor options cannot be omitted, e.g. you can set

  {h_ lab T}

  but not

  {h_ lab}

  as "T" sets the relation of "h_" to its "lab" neighbor.

The creation of a apave object and a paved window are rather straightforward. Firstly we package require apave, secondly we create the pave object, at last we make the window, this way:

package require Tk
package require apave
apave::APave create pobj
pobj makeWindow $win $title

To populate ("pave") the window with widgets, the paveWindow method is called, as discussed below.

An apave object can be used for paving various windows. When you end a work with a window and close it, usually you destroy it. However, its paving apave object can be freely applied to another window.

This work flow is well fit for hierarchical modal dialogues. You keep, say, obDlg1, obDlg2, obDlg3... apave objects for 1st, 2nd, 3rd... levels. Thus, you have a control over how deep is your dialogues' chain, as getting it too deep (more than 4 levels) is a bad practice. If your design requires obDlg5 (or even obDlg4), it's really a cause to revise it.

Other dialogue windows may be open as non-modal, working independently. Their paving apave objects may be named more specifically, say obFind, obCheck etc. Some modal windows (like regular messages) can be paved specifically too, say, with obMsg object.

That said, one apave object cannot pave two windows simultaneously.

The widget option list is passed to paveWindow method as a second argument, this way:

pobj paveWindow $win $widget_option_list

where:

• Widget name is a relative pathname of widget (e.g. butOK, fra1.lab1)
• Neighbor name is a neighboring widget's pathname or "-" (no neighbor) or "#" (no neighbor and no grid/pack)
• Position of neighbor may be "L" (left neighbor), "T" (top neighbor) or "-" (no neighbor)
• Row span is a rowspan grid option (optional, by default equals to 1)
• Column span is a columnspan grid option (optional, by default equals to 1)
• grid/pack/add options is a grid/pack/add options (optional)
  by default the options refer to the grid, however when the options begin with "pack", "pack forget" or "add" they refers to pack or add commands (add command is used as add ?options? command of ttk::panedwindow)
• Widget attributes is a widget attributes according to its type e.g. "label", "ttk:button" etc. (optional)

The widgets are included in the list normally from top to bottom and from left to right. The widgets succession in the list defines their tab order in the window, so you can define the successive widgets according to your requirements.

The widgets should be previously defined in the list to use them as neighbors.

In apave, the initial three letters of widget name define its type. This method (sort of Hungarian notation) saves a lot of keypressing.

The compound widget paths have the widget type according to the tail (e.g. fra1.but1 is of ttk::button type).

The ttk::widgets have the lower case patterns while their non-ttk counterparts have an uppercased 3rd letter (e.g. but vs buT).

Also, a widget name can have a first letter in the upper case. Though prohibited by Tk, this will create the normal "lower-cased" widget and the appropriate method to access its path. For example:

apave::APave create ::pObj
set ::win .win
::pObj makeWindow $::win.fra "Test"
::pObj paveWindow $::win.fra {
  {But1 - - 1 1 {} {-t "Button 1" -com {puts "Pressed [::pObj But1]"; ::pObj res $::win 1}}}
  {But2 but1 T 1 1 {} {-t "Button 2" -com {puts "Pressed [::pObj But2]"; ::pObj res $::win 2}}}
}
set res [::pObj showModal $::win]
puts res=$res
::pObj destroy
destroy $::win

The widget name patterns and their matters are presented in the table below.

{fra.nbk - - - - {pack -side top} {
  f1 {-text " 1st tab of General " -underline 2}
  f2 {-text " Ttk demos/ttkpane.tcl " -underline 1}
  f3 {-text " Non-themed " -underline 1}
  f4 {-text " Misc. widgets " -underline 1}
  f5 {-text " Color schemes " -underline 1}
  -traverse yes -select f2
}}

{frAT fra1 T 1 2 {-st nsew -rw 1 -pady 7}}
{frAT.textNT - - - - {pack -side left -expand 1 -fill both} {-h 11 -wrap none}}
{frAT.sbv frAT.textNT L - - {pack -after %w}}
{frAT.sbh frAT.textNT T - - {pack -before %w}}

{fraD labD L 1 1 {-st nswe -padx 5} {}}
{fraD.texD - - 1 1 {pack -side left -expand 1 -fill both} {-h 8 -w 50 -wrap word}}
{fraD.sbv fraD.texD L 1 1 {pack}}

{labtbl1 labBftx1 T 1 1 {-st e} {-t "Tablelist widget:"}}
{frAT labtbl1 L 1 9 {-st ew -pady 15}}
{frAT.Tbl1 - - - - {pack -side left -fill x -expand 1} {
  -h 7 -lvar ::t::tbllist  -lbxsel but -columns {$::t::tblcols}}}
{frAT.sbv frAT.tbl1 L - - {pack}}

Mega-Widget Names

The pickers (fil, fis, dir, fon, clr) have counterparts with a combobox instead of an entry.

{tcl {
  set prt BuTClrB
  for {set i 0} {$i<48} {incr i} {
  set cur "BuTClr$i"
  if {$i%4} {set n $pr; set p L} {set n $prt; set p T; set prt $cur}
  set pr $cur
  set lwid "$cur $n $p 1 1 {-st nsew -rw 1 -cw 1} {-com \
     {::t::toolBut 4 $i} -t \"Color scheme $i\n[t::pave csGetName $i]\"}"
  %C $lwid
  }
}}

Mega-Widgets

  {labfil1 - - - - {-st e} {-t "Choose a file to read....."}}
  {fil1 labfil1 L 1 1 {} {-tvar ::fil1 -title {Choose a file}}}

  {labfis1 - - - - {-st e} {-t "Choose a file to save....."}}
  {fis1 labfis1 L 1 1 {} {-tvar ::fis1 -title {Save as}}}

  {labdir1 - - - - {-st e} {-t "Choose a directory........"}}
  {dir1 labdir1 L 1 1 {} {-tvar ::dir1 -title {Choose a directory}}}

  {labfon1 - - - - {-st e} {-t "Choose a font............."}}
  {fon1 labfon1 L 1 1 {} {-tvar ::fon1 -title {Choose a font}}}

  set res [::apave::obj chooser fontChooser tvar {*}$args]

  where:
  tvar - name of variable containing a font attributes
  args - options of tk fontchooser
  res - gets a font chosen or {}

  {labclr1 - - - - {-st e} {-t "Choose a color............"}}
  {clr1 labclr1 L 1 1 {} {-tvar ::clr1 -showcolor 0 -title {Choose a color}}}

  {labdat1 - - - - {-st e} {-t "Choose a date............."}}
  {dat1 labdat1 L 1 9 {} {-tvar ::dat1 -title {Choose a date} -dateformat %d.%m.%Y}}

  set res [::apave::obj chooser dateChooser datevar -parent $win -dateformat %D]

  where:
  datevar - variable name to set a date
  win - parent window (to center the date picker inside it)
  res - gets a date chosen or {}

{lab - - 1 1 {-st nswe} {-t {Calendar:}}}
{daT lab T 1 1 {-st nw} {-relief raised -tvar ::dateKlnd
-dateformat $::formatKlnd -com {puts date1=$::dateKlnd} -locale en_us}}

  {Menu - - - - - {-array {
  File "&File"
  Edit &Edit
  help "&{Help (wordy)} -state normal -menu .win.menu"
   }}}

  [pobj Menu] entryconfigure 2 -font {-slant roman -size 10}
  [pobj File] entryconfigure 2 -state disabled

  proc ::NS::fillMenu {} {
  set m [::NS::pobj File]
  $m add command -label "Open..." -command \
    {error "this is just a demo: no action for \"Open...\""}
  $m add command -label "New" -command \
    {error "this is just a demo: no for \"New...\""}
  # ...
  }
  # ...
  pobj paveWindow .win.fra {
  # ...
  # widget list
  # ...
  }
  after idle [list ::NS::fillMenu]

  # create images for toolbar
  foreach {i icon} {0 retry 1 add 2 delete 3 undo 4 redo 5 run} {
  image create photo Img$i -data [::apave::iconData $icon]
  }
  # ...
  pobj paveWindow .win.fra {
  {tool - - - - {pack -side top} {-array {
    Img1 {{::t::toolBut 1} -tooltip "Start progress" -state disabled}
    h_ 3
    Img2 {{::t::toolBut 2} -tooltip "Stop progress"}
    sev 7
    h_ 1
    Img5 {{::t::e_menu} -tooltip "Run e_menu"}
    sev 7
    h_ 1
    Img3 {{::t::toolBut 3 \[set ::t::prevcs\]}}
    h_ 1
    opcTool {::t::opcc ::t::opcColors {-width 20} {t::opcToolPre %a} -command t::opcToolPost -tooltip "Current color scheme"}
    h_ 1
    Img4 {{::t::toolBut 4 \[set ::t::nextcs\]}}
    h_ 4
    ChbRestart {-var ::t::restart -t "Restart" -tooltip "To restart test2\nif CS changes"}
    sev 8
    h_ 1
    spX  {-tvar ::t::fontsz -command {::t::toolBut 4 -3} -from 9 -to 12 -w 3 -justify center -tooltip "Font size 9..12" -myown {
      puts "\nA local/global configuration may be set with -myown attribute, e.g.\
        \n  %w configure -bg yellow -font {-weight bold}\
        \n  ::NS::GLOBAL_CONFIG %w"}}
  }}}
  # ...
  }

  [pobj BuT_Img3] configure -state normal

  {lfrB.staMain - - - - {pack -side bottom} {-array {
  {Row:       -font {-slant italic -size 10}} 7
  {" Column:" -font {-slant italic -size 10}} 5
  {"" -font {-slant italic -size 10} -anchor w} 40
  }}}

  [pobj LabstaMain_1] configure -text "Height:"
  [pobj LabstaMain_2] configure -text " Width:"
  [pobj LabstaMain1] configure -text "100"
  [pobj LabstaMain2] configure -text "200"
  [pobj LabstaMain3] configure -text "3d cell's content"

  {fcoMain - - - - {pack} {-tvar ::fcoVar -w 88 -values {
  TEXT1
  @@-div1 \" (\" -div2 ) -ret true test1.txt@@
  TEXT2
  @@-pos 0 -len 7 -list {a b c} test2.txt@@
  ...
  TEXTN
  }}}

  @@-RE {^(\s*)([^#]+)$} ./test2_pave.tcl@@

  pobj configure edge "@|@"

  {fco - - - - {pack} {-tvar t::cb3 -w 88 -values {COMMIT: @@
  -div1 " \[" -div2 "\] " -ret true test2_fco.dat @@   INFO: @@
  -pos 22 -list {{Content of test2_fco.dat} {another item} trunk DOC}
  test2_fco.dat@@
  }}}

  {flb - - - - {pack -side left -fill x -expand 1}
  {-lvar ::t::lv1 -w 50 -values
  {@@-div1 " \[" -div2 "\] " test2_fco.dat@@   INFO: @@
  -pos 22 -ret 1 -list {{Content of test2_fco.dat} {another item} trunk DOC}
  test2_fco.dat@@
  }}}

  {
  ftxMain labBftx1 L 1 9 {} {
  -h 7 -ro 0 -tvar ::t::ftx1 -title {Pick a file to view}
  -filetypes {{{Tcl scripts} .tcl} {{Text files} {.txt .test}}}
  -wrap word}
  }

  set file_name $::t::ftx1
  set text_content [::pobj getTextContent ::t::ftx1]

  set res [pdlg vieweditFile mytext.txt "" -w 80 -h 24 -rotext ::temp]
  puts "Result: $res. Content of text:\n$::temp"
  unset ::temp

  set res [pdlg vieweditFile $filename "" -w 80 -h 20 -rotext ::temp -ro 0 -pos 10.0  -centerme .win -myown {puts %w} -weight bold]

proc ::NS::prepost_edit {dataName {wtxt ""}} {
  upvar 1 $dataName data
  # ... code ...
  if {$wtxt eq ""} {
  # it's PRE code ...
  } else {
  # it's POST code ...
  }
}

  set ::t::opcItems [list {{Color list} red green blue -- {colored yellow magenta cyan
  | #52CB2F #FFA500 #CB2F6A | #FFC0CB #90EE90 #8B6914}} \
  {hue dark medium light} -- {{multi word example}} ok]
  ...
  {.lab1 - - - - {-st e} {-t " 1st way, good:"}}
  {.Opc1 frAopc.lab1 L 1 1 {-st w} {::t::opcvar ::t::opcItems {-width -4} \
    {t::opcPre %a} -command t::opcPost }}
  ...

set emdir "some-location-of-e_menu-utility"
source [file join $::emdir e_menu.tcl]
# ...
::em::main -prior 1 -modal 1 -remain 1 {*}$e_menu_args

{.lfrB.BtsBar  - - - - {pack -side top -fill x} {::t::fillBarTabs %w}}

{LabImg fraflb T 1 1 {} {-link "::t::goWiki@@Click to go wiki@@"}}
{LabImgInfo LabImg T 1 1 {} {-link "
::t::chanTab nbk .win.fra.fra.nbk.f4; focus [::t::pave SpxMisc]@@Click to select 'Misc.'\n... and paint the link\n(to test the multiple visited links).@@" -afteridle ::t::labelImaged}}

#...
proc ::t::labelImaged {} {
  pave labelFlashing [pave LabImg] [pave LabImgInfo] 1 \
  -file {1-small.png 2-small.png 3-small.png 4-small.png} \
  -label {"Cisticola exilis" "Titmouse" "Wheatear" "Eurasian wren"}
}

  set ::t::textTags [list [list "linkVis" "::t::browser %t@@https://%l@@1"]]
  lassign [apave::obj csGet] fg fg2 bg bg2
  lappend textTags "FG $fg2" "FG2 $fg" "BG $bg2" "BG2 $bg"

set ::t::textTags [list \
  [list "linkVis" "::t::browser %t@@https://%l@@1"] \
  [list "link1" "::t::browser %t@@https://%l@@"] \
  [list "link2" "::t::browser %t@@https://aplsimple.github.io/en/tcl/%l/%l.html@@"] \
  [list "link3" "::t::browser %t@@https://wiki.tcl-lang.org@@"]]
:t::msg info "  Details:
   \u2022 <linkVis>aplsimple.github.io/en/tcl/pave</linkVis>
   \u2022 <link1>aplsimple.github.io/en/tcl/e_menu</link1>
   \u2022 <link1>aplsimple.github.io/en/tcl/bartabs</link1>
   \u2022 Reference on <link2>hl_tcl</link2>

  License: MIT.
  _____________________________________

   $::tcltk_version  <link3></link3>" \
  -t 1 -w 41 -scroll 0 -tags ::t::textTags -my "after idle {::t::showLogo %w}"

proc ::t::showLogo {w} {
  pave labelFlashing [pave textLink $w 4] "" 1 \
  -file feather.png -pause 0.5 -incr 0.015 -after 20
}

  {.lfrB.GutText1 .lfrB.stat T - - {pack -side left -expand 0 -fill both} {}}
  {.lfrB.Text1 .lfrB.canLines T - - {pack -side left -expand 1 -fill both} {-gutter GutText1 -gutterwidth 5 -guttershift 4 -w 80 -h 10 -wrap word}}
  {.lfrB.sbv .lfrB.text L - - {pack -side top}}

{v_ - - 1 1}
{fra v_ T 1 1 {-st nsew -cw 1 -rw 1}}
{fra.scf - - 1 1  {pack -fill both -expand 1} {-mode y}}
{.labU - - 1 1 {-st w -pady 1 -padx 3} {-t "User name:"}}
{.entU .labU L 1 1 {-st sw -pady 5} {-tvar alited::al(TPL,%U) -w 40}}

proc defaultAttrs {{type ""} {opts ""} {attrs ""} {widget ""}} {
  # Sets, gets or registers default options and attributes for widget type.
  #   type - widget type
  #   opts - new default grid/pack options
  #   attrs - new default attributes
  #   widget - Tcl/Tk command for the new registered widget type

ttk::style map Toolbutton {*}[dict replace [ttk::style map Toolbutton] \
  -foreground "pressed $fg1 active $fg1" -background "pressed $bg1 active $bg1"]
defaultAttrs btt {} {-style Toolbutton -compound top -takefocus 0} ttk::button
defaultAttrs brt {} {-style Toolbutton -compound right -takefocus 0} ttk::button
defaultAttrs blt {} {-style Toolbutton -compound left -takefocus 0} ttk::button

Mega-Attributes

-myown {%w configure -bg yellow -font {-weight bold}}

-myown {::NS::ATTR_THIS %w}
-myown {::NS::ATTR_THAT %w}

Option Abbreviations

APave Methods

pobj makeWindow win ttl

where:

  win is the window pathname
  ttl is the window's title

pobj paveWindow win lwidg

where:

  win    is the window pathname
  lwidg  is the list of widgets' options

pobj res win ?val?

where:

  win is the window pathname
  val is the value of variable for closing the window
       (if "val" omitted, "pobj res" returns the variable value)

pobj displayTaggedText txtWidg txtName txtTags

where:

  txtWidg is the text widget pathname
  txtName is the name of variable containing the text
  txtTags is the list of tags

showModal method

pobj showModal win args

where:

  win  - the window pathname
  args - the optional arguments

-waitme ::var_to_wait  ;# deiconified after changing the variable
-waitme 1000  ;# deiconified after 1 second
-waitme idle  ;# deiconified after idle
-waitme {idle after 1000}  ;# deiconified after idle and 1 second
 

pobj setShowOption -escape 0
pobj setShowOption -resizable 1

proc ::doClose {varName} {
  # varName is the name of variable that can be changed to 0 (1) in order to close the window.
  # This value is returned by pobj showModal.
  if {[tk_messageBox -type yesno -message "Quit?"] eq {yes}} {
    set $varName 0
  }
}
...
pobj showModal .win -focus *.ent1 -geometry +200+100 -onclose ::doClose

Theming of APave

  apave::initWM ?-option value...?

  where -option may be:
  -theme        - ttk theme (default, clam, alt etc.)
  -cs           - color scheme
  -cursorwidth  - cursor width
  -buttonwidth  - button width
  -buttonborder - button border
  -labelborder  - label border
  -padding      - padding for buttons and labels

  pobj csSet cs win

  where:
  cs - index of a color scheme
  win - window's path ("." if omitted)

  pobj csToned cs hue

  where:
  cs - index of a color scheme
  hue - value of hue (-99 through 99, from dark to light)

  APave create pobj $win $cs

  pobj themeWindow win fg1 bg1 fg2 bg2 fgS bgS fgD bgD cur bclr hlp fgI bgI fgM bgM isCS args

  pobj themeWindow . white #364c64 #d2d2d2 #292a2a white #4a6984 grey #364c64 #02ffff #00a0f0
  ...
  pobj showModal .win1 -geometry +300+80 -decor 1 -onclose ::ns::exitWin1
  ...
  pobj showModal .win2 -geometry +400+80 -decor 1 -onclose ::ns::exitWin2
  ...

  set fs [pobj basicFontSize]  ;# to get a current font size
  pobj basicFontSize $fs       ;# to set a new font size

  set fs [apave::paveObj basicFontSize]  ;# to get a current font size
  apave::paveObj basicFontSize $fs       ;# to set a new font size

More Examples of APave

package require apave
set win .win
apave::APave create pdlg
pdlg makeWindow $win "Adding Shortcuts"
set fontbold "-font \"-weight bold\""
pdlg paveWindow $win {
  {frAU - - 1 6   {-st new} {-relief groove -borderwidth 1}}
  {frAU.v_00 - - 1 1}
  {frAU.laB0 frAU.v_00 T 1 1 {} {-t "This TKE plugin allows you to create the shortcuts bound to existing ones. Thus you can enable localized shortcuts."}}
  {frAU.laB1 frAU.laB0 T 1 1 {} {-t "You can also make a miscellany that contains: event handler(s), menu invoker(s), command caller(s)."}}
  {frAU.laB2 frAU.laB1 T 1 1 {} {-t "Press the shortcut in the ID field. Confirm your choice by pressing Enter / Return key."}}
  {frAU.v_0 frAU.laB2 T 1 1}
  {v_0 frAU T 1 6}
  {laB1 v_0 T 1 2 {} {-t " Group info " $fontbold}}
  {laB2 laB1 T 1 1 {-st e} {-t "Name:"}}
  {entOrig laB2 L 1 1 {-st we -padx 5 -cw 3} {-tvar adsh__No}}
  {v_1 laB2 T 1 2}
  {laB3 v_1 T 1 1 {} {-t " Shortcut info " $fontbold}}
  {laB4 laB3 T 1 1 {-st e} {-t "Name:"}}
  {entName laB4 L 1 1 {-st we -padx 5} {-tvar adsh__Na}}
  {laB5 laB4 T 1 1 {-st e} {-t "Shortcut ID:"}}
  {entID laB5 L 1 1 {-st we -padx 5} {-tvar adsh__ID -state readonly}}
  {v_2 laB5 T 1 1 {-pady 8}}
  {laB12 v_2 T 1 1 {-st e} {-t "Type:"}}
  {cbxTyp laB12 L 1 1 {-st w -padx 5 -cw 3} {-tvar adsh__Typ -width 10 -values {MENU EVENT COMMAND} -state readonly}}
  {laB52 laB12 T 1 1 {-st en -rw 1} {-t "Contents:"}}
  {fraComm laB52 L 1 1 {-st nswe -padx 5} {}}
  {texComm - - 1 1 {pack -side left -expand 1 -fill both -in $win.fraComm} {-h 6 -w 50 -fg black -bg white -wrap word}}
  {sbvComm texComm L 1 1 {pack -in $win.fraComm}}
  {laB53 laB52 T 1 1 {-st en -rw 1} {-t "Description:"}}
  {fraDesc laB53 L 1 1 {-st nswe -padx 5} {}}
  {texDesc - - 1 1 {pack -side left -expand 1 -fill both -in $win.fraDesc} {-h 8 -w 50 -state disabled -wrap word}}
  {sbvDesc texDesc L 1 1 {pack -in $win.fraDesc}}
  {v_3 laB53 T 1 2}
  {laBSort v_3 T 1 1 {} {-t " Options " $fontbold}}
  {frAOpt laBSort L 1 1 {-st nsew}}
  {chBActive - - 1 1 {-in $win.frAOpt} {-t " Active " -var adsh__active}}
  {chBAuto chBActive L 1 1 {-in $win.frAOpt} {-t " AutoStart " -var adsh__auto}}
  {chBSort chBAuto L 1 1 {-in $win.frAOpt} {-t " Sorted list " -var adsh__sort -com adsh__sortToggle}}
  {v_4 laBSort T 1 2 {-rsz 10} {}}
  {fra v_4 T 1 2 {-st e -padx 5} {-relief groove -borderwidth 1}}
  {fra.butInsert - - 1 1 {-st w} {-t "Add" -com adsh__addItem}}
  {fra.butChange fra.butInsert L 1 1 {-st w} {-t "Change" -com adsh__changeItem}}
  {fra.butDelete fra.butChange L 1 1 {-st w} {-t "Delete" -com adsh__deleteItem}}
  {fra.h_ fra.butDelete L 1 1 {-padx 10}}
  {fra.butTest fra.h_ L 1 1 {-st w} {-t "Test" -com adsh__testItem}}
  {fraTr laB1 L 14 3 {-st nsew}}
  {tre1 - - 1 1 {pack -side left -in $win.fraTr -expand 1  -fill both} {-columns "ID A S"}}
  {sbv tre1 L 1 1 {pack -in $win.fraTr}}
  {v__u fra T 1 6}
  {seh v__u T 1 6}
  {laBMess seh T 1 2 {} "-foreground white -font \"-weight bold\""}
  {laBh_1 laBMess L 1 1 {-cw 1}}
  {fra2 laBh_1 L}
  {fra2.butApply - - 1 1 {} {-t "Apply" -com "adsh__doApply"}}
  {fra2.butOK fra2.butApply L 1 1 {} {-t "Save" -com "adsh__doSaveExit"}}
  {fra2.butCancel fra2.butOK L 1 1 {} {-t "Exit" -com "exit"}}
}
pdlg showModal $win -focus $win.entOrig -geometry +100+100 -decor 1

Below a screenshot of test2_pave.tcl of downloaded apave_tests.zip:

... and its themed version:

... and its themed non-ttk widgets:

... and here is a few of its videos:

• apave v3.4.6 - Overview
• apave v3.4.6 - Theming
• apave v3.2.7 - Dialogues
• apave v3.2.7 - Links

Probably, the most impressive usage of apave is presented by alited editor. Below are its screenshots of English and localized variants:

... and its themed variant on MS Windows 10:

Here is a video, just to glance at it: testing by playtkl package (recording and playback).

The APave oo::class provides a batch of standard dialogues that are enhanced by a checkbox (titled e.g. "Don't show again") and a tagged text option.

Also, the APave oo::class provides the input facilities. You can call it, e.g., to edit a file or put the data. The plugin applications are most suitable for these facilities as they allow storing the dialogues in the form of data files.

Description	Calling	Screenshot
A usual info dialog. A geometry (+X+Y) and a checkbox (-ch) are set.	apave::APave create dlg dlg ok info "Dialog OK" \ "Hey that Pushkin!\nHey that son of bitch!" \ -g +200+200 -ch "Don't show this again"
A retrycancel error dialog. The RETRY argument sets a focused button as the dialog opens.	apave::APave create dlg dlg retrycancel err "Dialog RETRYCANCEL" \ "Hey that Pushkin!\nHey that son of bitch! --- Retry the reading of Pushkin? Cancel if not." \ RETRY -g +300+300 -ch "Don't show this again"
A yesnocancel question dialog.	apave::APave create dlg dlg yesnocancel ques "Dialog YESNOCANCEL" \ "Hey that Pushkin!\nHey that son of bitch! --- Do you agree? Or hate the question? (Choose Cancel in such case)" \ YES -g +275+275 -ch "Don't show this again"
An abortretrycancel error dialog.	apave::APave create dlg dlg abortretrycancel err \ "Dialog ABORTRETRYCANCEL" \ "Hey that Pushkin!\nHey that son of bitch! --- Abort or retry the reading of Pushkin? \ Cancel if not sure." RETRY -g +325+325 \ -ch "Don't show this again"
A misc info dialog. By this dialog you can set as many and as various questions and answers as (reasonably) you want.	apave::APave create dlg set retval [dlg misc info "Dialog MSC" \ "\nAsk for HELLO\n" {Hello 1 {Bye baby} 2 \ Misc3 3 Misc4 4 "Misc 5" 5 Cancel 0 } 2]
An okcancel editing dialog. The dialog has a heading that is set as "-head" option. The icon is set as "" and as such is absent. The dialog is a small editor. Use Ctrl+F and F3 to find strings. The return values can include the cursor position used for the next call of this editorling.	apave::APave create dlg set textTags [list [list "dark" \ "-foreground black"] \ [list "b" "-font {-weight bold -size 14}"] \ [list "i" "-font {-slant italic -size 14}"]\ [list "red" "-foreground red"]] set res [dlg okcancel "" "Dialog OKCANCEL" \ " <dark>Hey that <red><b> Pushkin </b></red>! Hey that son of bitch! --- Do you agree? <i>Cancel</i> if not.</dark> " TEXT -g +250+250 -text 1 -tags textTags \ -width 30 -height 6 -bg white \ -head "When presented at first\nit's a \ \"changeable text message\"." \ -hsz "12 -slant italic -weight normal" \ -weight bold -size 12 -bg #ffffc4 -ro 0]
An input dialog. By this dialog you can get/put the data. All available widgets are presented in this code sample. After choosing "OK" the dialog would return the input values as a list.	apave::APave create dlg set rellist {- Father Mother Son Daughter \ Brother Sister Uncle Aunt Cousin \ {Big Brother} "Second cousin" "1000th cousin"} lassign "" \ ::ent ::fil ::fis ::dir ::fon ::clr ::dat \ ::chb ::rad ::spx ::lbx ::cbx ::fco ::tex set res [dlg input - "Dialog INPUT" [list \ seh1 {{} {-pady 9}} {} \ ent {{Enter general info........}} "{$::ent}"\ fil {{Choose a file to read.....}} "{$::fil}"\ fis {{Choose a file to save.....}} "{$::fis}"\ dir {{Choose a directory........}} "{$::dir}"\ fon {{Choose a font.............}} "{$::fon}"\ clr {{Choose a color............}} "{$::clr}"\ dat {{Choose a date.............}} "{$::dat}"\ seh2 {{} {-pady 9}} {} \ chb {{Check the demo checkbox...}} $::chb \ rad {{Check the radio button....}} [list \ "$::rad" Giant Big Small "None of these"] \ seh3 {{} {-pady 9}} {} \ spx {{Spinbox from 0 to 99......} {} \ {-from 0 -to 99}} $::spx \ lbx [list {Listbox of relations......} {} \ [list -h 4 -lbxsel $::lbx]] $rellist \ cbx [list {Combobox of relations.....} {} \ [list -h 7 -cbxsel $::cbx]] $rellist \ fco [list {Combobox of file content..} {} \ [list -h 7 -cbxsel $::fco]] { \ @@-div1 " \[" -div2 "\] " -ret 1 \ test2_fco.dat@@ INFO: @@-pos 22 -list \ {test2_fco.dat {other item} trunk DOC} \ test2_fco.dat@@} \ seh4 {{} {-pady 9}} {} \ tex {{Text field................} {} \ {-h 4 -w 55}} $::tex \ ] -size 14 -weight bold -head "Entries,\ choosers, switchers, boxes..." {*}$args] lassign [dlg valueInput] \ ::ent ::fil ::fis ::dir ::fon ::clr ::dat \ ::chb ::rad ::spx ::lbx ::cbx ::fco ::tex
A yesno warning dialog (themed). The dialog is called in a cycle and breaks it if answered "Yes". The color (-c) of message is set as Tk standard color ("ghost white"). When the geometry is passed to a dialog, it returns [list answer geometry], so to get its answer the lindex command is used.	if {[lindex [ \ dlg yesno warn "UFF..." \ "\n Break the dance? \n" \ NO -g +350+350 -weight bold -size 22 \ -c "ghost white" \ ] 0] == 1} break

The stanzas on links might be chanted here. Any line (in fact, ttk::label) of dialog's message can be supplied with a link. And any of the text's parts may be tagged with a link. The appropriate code samples can be found in test2_pave.tcl ("Help/About" dialog) and test_pavedialog.tcl ("RetryCancel" dialog) of downloaded apave_tests.zip

Any of dialog buttons (Yes/No/Cancel etc.) may be set as "timeouted", i.e. it may be run after expiring an interval in seconds. See below -timeout option.

Below is a list of APave dialogue options, with their short / full names. Any option outside the list is considered to be an attribute of the message font.

• -ch / -checkbox value sets a checkbox message
• -g / -geometry +X+Y sets a geometry of dialog
• -c / -color value sets a foreground color for labels
• -H / -head value sets a header
• -t / -text 1 sets a text widget instead of labels
• -tags value sets a tags list for the text message
• -modal 0 shows the dialog as a non-modal window
• -ro / -readonly 0 makes the text editable
• -w / -width value sets a width of text in characters which can be a range {min max}
• -h / -height value sets a height of a text in lines which can be a range {min max}
• -fg value sets a foreground color for text
• -bg value sets a background color for text
• -fgS value sets a selection foreground color for text
• -bgS value sets a selection background color for text
• -hfg value sets a foreground color for header
• -hbg value sets a background color for header
• -hsz value sets a font size color for header
• -cc value sets a cursor color for text
• -pos nl.nc sets a cursor position for text
• -root w sets a root window (to center the dialog)
• -ontop 1 sets the dialog on the top of the screen
• -timeout {sec wbut} sets a timeout in seconds to invoke wbut button's command; wbut is of ButOK/ButNO/ButCANCEL etc. or "Lab<number>" form, for example -timeout {3 ButOK} or -timeout {3 Lab1}.
• -focus w focuses on a widget at opening the input dialog
• -scroll 0 switches the vertical scroll bar off (for the text dialogues)
• -my / -myown {command %w} sets a command to provide additional attributes
• -help / -help {command %w} sets Help button of a dialogue and a command for it (can be also: -buttons "butHELP {Title} {command}")
• -buttons / -buttons {but1 ttl1 res1 but2 ttl2 res2 ...} sets triples button & title & result for additional buttons of input dialogue; for example: -buttons {butChange {Edit it} 3 butUndo {Undo it} 4 butRedo {Redo it} 5}

To call the input dialog, use the following syntax:

  APave create dlg
  set res [dlg input icon title widgets ?dialog options?]
  dlg destroy

where:

• icon is info, warn, err, ques or ""
• title is a title of dialog window
• widgets is a list of lists containing three elements:
  • name of field is a widget name that also sets its type:
    • seh - horizontal separator
    • lab - label
    • ent - entry
    • fil - file chooser (to read)
    • fis - file chooser (to save)
    • dir - directory chooser
    • clr - color chooser
    • dat - date chooser
    • chb - checkbox
    • rad - radiobutton
    • spx - spinbox
    • lbx - listbox
    • tbl - tablelist
    • opc - tk_OptionCascade
    • cbx - combobox
    • fco - file content combobox
    • tex - text
    • but - button
  • prompt and options is a list of three (or less) elements:
    • prompt - a prompt for the field or {}, e.g. "Login:"
    • grid options - grid options of the field or {}, e.g. "-pady 5"
    • attributes - attributes of the field, e.g. "-h 4 -w 40";
      • but and chb widgets have "-toprev 1" attribute to be attached to a previous widget (e.g. in 'Project...' of e_menu utility)
  • values' options is a list that depends on the type of widget:
    • for tex - a current content of text (\n to be newlines, \t tabs)
    • for lbx, cbx, rad, tbl, opc - a current value and a list of items, e.g. "{in file} {in file} {in session} {in directory}"
    • for fco - a content of -values option
    • for others - a current value
• dialog options are options used by APave dialogues (described above)

The APave input dialog returns a list containing:

• main result (1 for OK, 0 for Cancel)
• others values, depending on a call syntax

To get the variables' values, use valueInput method, this way:

lassign [dlg valueInput] varname1 varname2 varname3 ...

Example:

set res [dlg input ques "My site" [list \
  entLogin {{Login......}} aplsimple \
  entPassw {{Password...} {} {-show *}} {} \
] -weight bold -head "\n Enter to register here:"]
if {[lindex $res 0]} {lassign [dlg valueInput] login password}

For a detailed example, see tests/test_pavedialog.tcl of downloaded apave_tests.zip.

The APave class is heavily used in e_menu's dialogues and apavecli.tcl described below.

This feature is implemented by apavecli.tcl that allows to run apave dialogues from shell / CLI.

As a rule, the apavecli.tcl dialogues contain OK/Cancel (by default) or Yes/No buttons. After choosing OK or Yes, the dialog sets 1 as its result and writes its output to stdout.

The output of apavecli.tcl would be sort of:

#!/bin/bash
export var1='value 1'
export var2='value 2'
...
export varN='value 3'

The output may be redirected to a temporary file. After analizing the result of dialog (1 if OK/Yes, otherwise 0), the temporary file may be sourced to execute the "export ..." commands. So that the dialog's variable values would be assigned to the environment variables within the current shell.

Example:

tclsh ~/UTILS/pave/apavecli.tcl ques "My site" \
  { entLogin {"Login......"} {} \
  entPassw {"Password..."  {} {-show *}} {} \
  } -weight bold -head "\n Enter to register here:" \
  -titleOK "Yes" -titleCANCEL "No" \
  == LOGIN PASSW > tmp.sh
if [ $? -eq 1 ]; then source tmp.sh; fi; rm tmp.sh
echo "Login: $LOGIN"; echo "Password: $PASSW"

The dialog would look like the above shown. That's no wonder, because the same APave input interface is used here.

The -titleOK "Yes" -titleCANCEL "No" arguments redefine buttons' labels. By default the buttons are labeled OK and Cancel.

The == LOGIN PASSW > tmp.sh arguments define LOGIN and PASSW output variables and redirect their assignment to tmp.sh file. After checking the command's result, the tmp.sh file is executed by source. As a result, LOGIN and PASSW environment variables are set within the current shell. The echo command is one of many ways of their usage.

Below is the dialog and its CLI command:

... and the result of echo commands:

If necessary, the dialog may only contain a message and OK/Cancel buttons, omitting any input:

tclsh ~/UTILS/pave/apavecli.tcl warn "Git rebase" {} -head \
"Now we'll be git rebase.\nPress \"OK\" to continue..."

...as seen below:

If necessary, the Cancel button may be omitted by use of -titleCANCEL "":

tclsh ~/UTILS/pave/apavecli.tcl warn "Git rebase" {} \
-head "Now we'll be git rebase.\nPress \"OK\" to continue..." \
-weight bold -titleCANCEL ""

...as seen below:

See also an example in comments of apavecli.tcl of downloaded apave_tests.zip.

Note: It would be convenient to have a symbolic link to executable apavecli.tcl. Thus, you can use e.g. apavecli instead of wordy tclsh ~/UTILS/pave/apavecli.tcl.

This link should be located on your $PATH and have 'pave' subdirectory under it. Your directory tree may look like this:

 ~/UTILS             (dir on $PATH)
   apavecli           (link)
   pave              (subdir)
   obbit.tcl
   apavedialog.tcl
   ...
   pkgIndex.tcl

  tclsh ~/SOME/WHERE/pave/apavecli.tcl "$@" 

These tips & tricks are mostly taken from test2_pave.tcl of downloaded apave_tests.zip.

1. A button / label widget with a bound command to fire after a timeout

This feature is available for APave dialogues.

At calling a APave dialogue, you can pass it -timeout option like:

• -timeout {3 ButOK} for "OK" button to have 3 seconds timeout
• -timeout {3 Lab1} for a first label to have 3 seconds timeout

For example:

  pobj ok info {Button Pressed} {That hurt...} -root .win -head {Ouch! Wow!\nMiau!} -weight bold -timeout {5 Lab1}

2. A progress form for a boot process presumably long

If some GUI application at starting creates a lot of widgets and does other initializations so that this process can take a while, say 4-5-6... seconds, it would be reasonable to run a progress form before calling paveWindow method and other things.

The progress form is called this way:

  pobj progress_Begin $type $win $title $topmsg $botmsg $maxvalue -length $length
  ... processing ...
  pobj paveWindow $win \
  ....
  ... processing ...
  pobj progress_End

• $type is a type of this progress form (unique sequence of characters)
• $win is a parent window to center the progress form in
• $title is a title of the progress form
• $topmsg is a top message or {}
• $botmsg is a bottom message or {}
• $maxvalue is a maximum value of progress
• -length $length are optional arguments of ttk::progressbar widget (can be continued by others)

Normally, progress_Begin begins and progress_End ends the progress show.

In between, to add a progress value, you can use the following:

  pobj progress_Go $value $msg1 $msg2

• $value is a value to add to the progress
• $msg1 is a top message or {}
• $msg2 is a bottom message or {}

If the $type argument of progress_Begin is equal to {}, the paveWindow of APave object participates in the progress too, namely: each widget's creation adds 1 to the progress by calling progress_Go.

Also, if $type equals to {}, at ending the progress there will be put out a small statistics of the progress: maximum value, current value, number of steps. It's useful for the customization of $maxvalue argument of progress_Begin.

See an example in test2_pave.tcl of downloaded apave_tests.zip.

3. Blinking widgets to draw attention

To get a widget blinking, use the following:

  ::apave::blinkWidget $w $fg $bg $fg2 $bg2 $pause $count

• $w is a widget's path
• $fg is a normal foreground color
• $bg is a normal background color
• $fg2 is a blinking foreground color (if {}, stops the blinking)
• $bg2 is a blinking background color
• $pause is a pause in millisec between blinkings
• $count is a number of blinkings

4. Configurable balloon messages and tooltips

For most widgets, apave provides "-tip" or "-tooltip" attribute processed by baltip package.

Also, you can use the baltip package independently in specific cases, for example to display a balloon message.

Refer to the baltip's Reference for further details.

There is menuTips method allowing to tip a menu, an option cascade and their items, declared as:

method menuTips {win tip {wpar {}}}
#   win - menu's path
#   tip - tip's text
#   wpar - path to menu's parent (for an option cascade)

The tips for menu items are set by -indexedtips ?idx tip...?.
For example, a tip can be set as:

set tip "whole tip -indexedtips 0 firstTip 9 {for tenth item} 11 {tip for #12}"

5. Customized dimensions of Tcl/Tk Unix's file / directory choosers

To set the choosers' geometry (before calling them), use the following:

  ::apave::setProperty DirFilGeoVars [list dirgeoVar filgeoVar]

• dirgeoVar is a variable name for directory chooser's geometry
• filgeoVar is a variable name for file chooser's geometry

To get the choosers' geometry (after calling them), use the following:

  lassign [::apave::getProperty DirFilGeoVars] dirgeoVar filgeoVar

6. Saving your keypresses

You can save your keypresses at paving a window by using "." as beginning character of widget name. This would mean that a widget name consists of a previous "normal" name + this name. For example:

...
{fral - - 8 1   {-st nes -rw 1}}
{.but1 -       - 1 1 {-st we} {-t "General" -com "t::chanTab nb"}}
{.but2 .but1 T 1 1 {-st we} {-t "View" -com "t::chanTab nb2"}}
{.but3 fral.but2 T 1 1 {-st we} {-t "Editor" -com "t::chanTab nb3"}}
...

• fral - a frame
• .but1 - a button ("General") in fral frame
• .but2 - a button ("View") in fral frame
• .but3 - a button ("Editor") in fral frame

Also, it occurs often that L/T neighbor is equal to a previous widget, like here:

...
{labB1 - - 1 1   {-st es}  {-t "First option:"}}
{ent1 labB1 L 1 9 {-st wes -cw 1} {-tvar t::en1}}
{labB2 labB1 T 1 1 {-st es}  {-t "Second option:"}}
{ent2 labB2 L 1 9 {-st wes} {-tvar t::en2}}
...

In this case you can use "+" for L/T neighbor, e.g. to simplify the previous example (two label / entry instances):

...
{labB1 - - 1 1   {-st es}  {-t "First option:"}}
{ent1 + L 1 9 {-st wes -cw 1} {-tvar t::en1}}
{labB2 labB1 T 1 1 {-st es}  {-t "Second option:"}}
{ent2 + L 1 9 {-st wes} {-tvar t::en2}}
...

7. Another method of keypress saving

Another method of keypress saving is a use of uppercased names. For example:

...
{.lfrB.Text - - - - {pack -side left -expand 1 -fill both} {-borderwidth 0 -w 76}}
...
[pobj Text] replace 1.0 end "...some text..."
...

• the real text widget is named something like .win.fra.and_so_on.lfrB.text (in test2_pave.tcl, its name is .win.fNB.nb.f2.fra.pan.panR.lfrB.text - a mess of notebook tabs, frames and panes)
• the Text method is created in paved object allowing to get the real name of widget through just [pobj Text]

8. Window name passed to apave

If the window name is passed to APave makeWindow and APave window methods as $win.fra :

pobj makeWindow $win.fra "Title"
pobj paveWindow $win.fra {
  {lab1 - - 1 1    {-st es}  {-t "Find: "}}
  ...
}

9. Container widgets outside of apave

If you have a batch of container widgets made outside of apave, you can pave them in one call of APave window method. For example:

pobj paveWindow .win.fNB.nb.f1 {
  ...
} .win.fNB.nb.f2 {
  ...
} .win.fNB.nb.f3 {
  ...
}

10. The widget list can include comments

The widget list passed to pobj window can include comments. They are recognized by the "#" as first symbol of widget name. After the "#" you can include multiline comments as well as just "###...###" to underline any blocks.

The comments are useful when you need to turn off this or that widget.

For example:

pobj paveWindow .win {
   ###<----it's-a-comment-(being-a-record-of-one-continuous-string)
   #
   {# <--- it's a comment mark (being first in a {...} record)

   Comments are marked by "#" as the 1st character of layout record.
   This is a multi-line comment.

   }
   ####################################################################
   {lab1 - - 1 1   {-st es}  {-t "First option:"}}
   {ent1 labB1 L 1 9 {-st wes -cw 1} {-tvar ::ent1}}
   ####################################################################
}

11. Navigation by arrows and Return/Enter key

The apave provides a navigation by arrows and Return for some widgets (entries, buttons, checkboxes etc.). You can switch off this behavior by including "STD" into a widget name. For example, frame.entrySTD would not participate in this navigation, so that only Tab & Shift+Tab would be enabling the keyboard navigation.

You can also change a tab order offered by apave by means of -tabnext attribute.

12. How to improve the performance a little

You can improve the performance by filling the menu contents (and doing other initializations) after paving a window. Use after idle (no wonder), e.g. this way:

pobj paveWindow .win.fNB.nb.f1 {
  ...
}
after idle [list ::NS::fillMenu_Binding_Etc $w]

You can also use -afteridle attribute for appropriate widgets.

At last, "after" clause can be used in the widget list as the first item, this way:

pobj paveWindow .win.fNB.nb.f1 {
  ...
} .win.fNB.nb.f2 {
  ...
} .win.fNB.nb.f3 {
  {after idle}
  ...
} .win.fNB.nb.f4 {
  {after 100}
  ...
}

13. On the window parenting

In my Debian, if I make .win window and call another .win1 window from .win, then the .win1 behaves as if it's an independent app at least in 2 aspects:

- it creates its own item in the desktop application bar
- it is overlapped by its caller (.win) if I click on it

The latter is most annoying.

Strangely, but even Paul Obermeier's great applications are made this way: when I run, say, "Directory diff" and open any dialogue from "Settings" menu or get a confirmation message, it's overlapped by the main window if it's unintentionally clicked or activated otherwise.

And on the contrary, if I call .win.win1 from .win, then I get rid of those "aspects". Instead, I get a nice bonus: when a caller is destroyed, its non-modal children are destroyed too.

I can have as many non-modal children as I like, say win.win1, win.win2, win.win3. And some windows can be modal, locking all others.

So, make your windows so that they had a parent. Of course, there should be a grandgrand..grandfather for all of them, say .win - the main window of an application. Then you make its child like .win.win1 and (possibly) grandchild like .win.win1.win2 and so on.

apave stuff is available here:

• Source

  • from chiselapp (pave.zip)
  • from github

• Reference
• Project printer


• Tests for apave
• Demo videos:
• apave v3.4.6 - Overview
• apave v3.4.6 - Theming
• apave v3.2.7 - Dialogues
• apave v3.2.7 - Links

Notice that apave is still disposed to update.

The links about and around apave:

The review of geometry management in Tcl/Tk:
https://wiki.tcl-lang.org/page/Geometry+Managers

The APave page on wiki.tcl-lang.org:
https://wiki.tcl-lang.org/page/Pave%2C+sort+of+geometry+manager